Gracias por la explicación!
Pero me refería a si Konami usaba la llamada a la BIOS FILVRM para pasar datos masivamente a VRAM o los out con el consiguiente problema que parece haber de los NOP para no saturar el VDP. Quizás es que no lo tengo muy claro porque hasta ahora "voy con mi FILVRM a todas partes"
Ya que pides algo mas concreto te pongo las rutinas que usaba Konami para hacer un FILVRM, junto a LDIRVM y LDIRMV. mas la rutina de copiar datos de VRAM a VRAM y con todo este codigo creo que tu pregunta quedará resuelta.
;----------------------------------------------------
; Rellena la VRAM
; DE = Direccion VRAM
; A = Dato
; BC = Numero de bytes
;----------------------------------------------------
setFillVRAM: ; ...
call SetVDPWrite
fillVRAM: ; ...
ex af, af'
VRAM_write2: ; ...
ex af, af'
exx
out [c], a
exx
ex af, af'
dec bc
ld a, b
or c
jr nz, VRAM_write2
ei
ret
; ---------------------------------------------------------------------------
fillVRAM_HL: ; ...
ld a, [hl]
inc hl
jr fillVRAM
; ---------------------------------------------------------------------------
;----------------------------------------------------
;
; Transfiere datos desde la RAM a la VRAM
; HL = Origen
; DE = Direccion de destino en la VRAM
; BC = Numero de datos
;
;----------------------------------------------------
HLtoVRAMset: ; ...
di
call SetVDPWrite
;----------------------------------------------------
;
; Transfiere datos desde la RAM a la VRAM
; HL = Origen
; BC = Numero de datos
;
;----------------------------------------------------
HLtoVRAM: ; ...
ld a, [hl]
exx
out [c], a
exx
inc hl
dec bc
ld a, b
or c
jr nz, HLtoVRAM
ei
ret
; ---------------------------------------------------------------------------
;---------------------------------
; Copia VRAM a VRAM
; In:
; HL = Origen
; DE = Destino
; BC = Numero de bytes a copiar
;---------------------------------
CopyVRAM: ; ...
call ReadVRAM
ex de, hl
call WriteVRAM
ex de, hl
inc hl
inc de
dec bc
ld a, c
or b
jr nz, CopyVRAM
ret
; ---------------------------------------------------------------------------
